EST

Cette section décrit les huit fonctions utilisées pour tester le type d'une valeur ou d'une référence de colonne.

Chacune de ces fonctions, regroupées sous le nom de fonctions EST, vérifie le type de valeur et renvoie VRAI ou FAUX selon le résultat. Par exemple, la fonction ESTVIDE renvoie la valeur logique VRAI si la valeur est une référence de colonne qui est vide ; sinon, elle renvoie FAUX.

Syntaxe

ESTVIDE(valeur)
ESTERR(valeur)
ESTERREUR(valeur)
ESTLOGIQUE(valeur)
ESTNA(valeur)
ESTNONTEXTE(valeur)
ESTNUM(valeur)
ESTTEXTE(valeur)

valeur est la valeur que vous voulez tester. La valeur peut être vide, erreur, logique, texte, nombre ou référence de colonne.

Fonction	Renvoie VRAI si
ESTERR	La valeur correspond à toute valeur d'erreur sauf #N/A.
ESTERREUR	La valeur correspond à toute valeur d'erreur (#N/A, #VALEUR!, #REF!, #DIV/0!, #NOMBRE!, #NOM? ou #NUL!).
ESTLOGIQUE	La valeur correspond à une valeur logique.
ESTNA	La valeur correspond à la valeur d'erreur #N/A (valeur non disponible).
ESTNONTEXTE	La valeur correspond à tout élément qui n'est pas du texte. (Notez que cette fonction renvoie VRAI si la valeur correspond à une référence de colonne vide.)
ESTNUM	La valeur correspond à un nombre.
ESTTEXTE	La valeur correspond à du texte.
ESTVIDE	La valeur correspond à une référence de colonne vide.

Remarques

Les arguments de valeurs des fonctions EST ne sont pas convertis. Par exemple, dans la plupart des fonctions où un nombre est requis, la valeur texte « 19 » est convertie en nombre 19. Cependant, dans la formule ESTNUM("19"), « 19 » n'est pas converti à partir d'une valeur texte et la fonction ESTNUM renvoie FAUX.
Les fonctions EST sont utilisées dans des formules pour tester le résultat d'un calcul. Lorsqu'elles sont combinées avec la fonction SI, elles constituent une méthode pour identifier des erreurs dans des formules (voir les exemples suivants).

Exemple 1

Formule	Description (résultat)
=ESTLOGIQUE(VRAI)	Vérifie si VRAI est une valeur logique (VRAI)
=ESTLOGIQUE("VRAI")	Vérifie si « VRAI » est une valeur logique (FAUX)
=ESTNUM(4)	Vérifie si 4 est un nombre (VRAI)

Exemple 2

Col1	Formule	Description (résultat)
Or	=ESTVIDE([Col1])	Vérifie si la valeur de Col1 est vide (FAUX)
#REF!	=ESTERREUR([Col1])	Vérifie si la valeur de Col1 est une erreur (VRAI)
#REF!	=ESTNA([Col1])	Vérifie si la valeur de Col1 est l'erreur #N/A (FAUX)
#N/A	=ESTNA([Col1])	Vérifie si la valeur de Col1 est l'erreur #N/A (VRAI)
#N/A	=ESTERR([Col1])	Vérifie si la valeur de Col1 est une erreur (FAUX)
330,92	=ESTNUM([Col1])	Vérifie si la valeur de Col1 est un nombre (VRAI)
Région1	=ESTTEXTE([Col1])	Vérifie si la valeur de Col1 est du texte (VRAI)